EnigmA Amiga Run 1997 February/EnigmA AMIGA RUN 15 (1997)(G.R. Edizioni)(IT)[!][issue 1997-02][PLANET CD V].iso/enigma/earcd/utility/utilmisc/mui-asl.lha/MUI-ASL/Install

Text File | 1996-11-12 | 6KB | 172 lines

;--------------------------------------------------------------------------
; $VER: MUI-ASL Installer script 1.0 (6.11.96) © Marcin Orlowski
; Written by Marcin Orlowski <[e-mail]>
;--------------------------------------------------------------------------
;
; History
; --------------------
; 10.11.96 14:32:08 - Initial release
;
;--------------------------------------------------------------------------

(set #lib-source "Libs")
(set #mcc-source "Libs/MUI")
(set #cat-source "Locale/Catalogs")
(set #lib-dest   "LIBS:")
(set #mcc-dest   "MUI:Libs/MUI")
(set #cat-dest   "LOCALE:Catalogs")

(procedure P_copylang
 (foreach (tackon #cat-source #lang) "#?.catalog"
  (copylib (source (tackon (tackon #cat-source #lang) @each-name))
           (dest (tackon #cat-dest #lang)))
 )
)

(set #def-lang-english     0)
(set #def-lang-deutsch     1)
(set #def-lang-español     2)
(set #def-lang-français    4)
(set #def-lang-italiano    8)
(set #def-lang-norsk      16)
(set #def-lang-svenska    32)
;(set #def-lang-polski     64)

(set @default-dest "")

;*** Strings ***

(if (= @language "italiano") (
  (set #bad-kick "Spiacente, MUI-ASL richiede il Kickstart 3.0 (V39) o successivo.")
  (set #bad-CPU  "Spiacente, MUI-ASL richiede almeno un 68020.")
  (set #bad-MUI  "Spiacente, MUI-ASL richiede MUI 3.3 o successiva.")

  (set #def-lang #def-lang-italiano)
  (set #lang-prompt "Scegli le lingue che userai con MUI-ASL\n(l'inglese è incorporato)")

  (set #rename-prompt "Rinominare \"%s\"\ncome \"%s\"?")
  (set #rename-help   "Manterrò la tua asl.library originale con un altro nome, così potrà essere ripristinata in caso di problemi con MUI-ASL.")

  (set #mcc-prompt "Vuoi copiare la classe MUI '%s' in '%s'?")
  (set #mcc-help   "Le classi MUI sono dei componenti aggiuntivi che estendono le funzionalità di MUI.")

  (set #help-prompt "Vuoi installare la guida in inglese in \"HELP:english\"?\n\n(spiacente, la guida in italiano non è disponibile... qualcuno vuole scriverla?)")
  (set #help-help   (cat "Copierò la guida in inglese in \"HELP:english\" (spiacente, la guida in italiano non è disponibile).\n\n"
                         "Se installi il file della guida, potrai avere una spiegazione sensibile al contesto nei requester di MUI-ASL premendo il tasto HELP."))

  (set #exit-message "Devi riavviare il computer per vedere MUI-ASL all'opera.\nBuon divertimento!")
)(
  (set #bad-kick "Sorry, MUI-ASL requires Kickstart 3.0 (V39) or later.")
  (set #bad-CPU  "Sorry, MUI-ASL requires at least a 68020.")
  (set #bad-MUI  "Sorry, MUI-ASL requires MUI 3.3 or later.")

  (set #def-lang #def-lang-english)
  (set #lang-prompt "Select languages you will use with MUI-ASL\n(English is built-in)")

  (set #rename-prompt "Rename \"%s\"\nas \"%s\"?")
  (set #rename-help   "I'll save your original asl.library under a different name, so that it can be restored in case of a problem in MUI-ASL.")

  (set #mcc-prompt "Do you want to copy the MUI custom class '%s' to '%s'?")
  (set #mcc-help   "The MUI custom classes are components that extend MUI functionality.")

  (set #help-prompt "Do you want to install the English help in \"HELP:english\"?")
  (set #help-help   (cat "I will place the English help in \"HELP:english\".\n"
                         "If you install the help file, you will be able to get context-sensitive help in MUI-ASL requesters by pressing the HELP key."))

  (set #exit-message "You have to reboot to see MUI-ASL at work.\nHave fun!")
))

;*** Checking environment ***

(complete 0)

(if (< (getversion "LIBS:version.library") (* 39 65536)) (
 (abort #bad-kick)
))

(if (< (database "cpu") 68020) (
 (abort #bad-CPU)
))

(if (not (exists "MUI:" (noreq))) (
 (abort #bad-MUI)
))

(set MUI_ver (getversion "MUI:Libs/muimaster.library"))
(if (AND (< MUI_ver (* 16 65536)) (<> MUI_ver 0)) (abort #bad-MUI))

;--------------------------------------------------------------------------
; choose language
(set #cat-lang
 (askoptions
  (prompt #lang-prompt)
  (choices
   "Deutsch"
   "Español"
   "Français"
   "Italiano"
   "Norsk"
   "Svenska"
;   "Polski"
  )
  (help @askoptions-help)
  (default #def-lang)
 )
)

(complete 10)

;--------------------------------------------------------------------------
(set #oldname "LIBS:asl.library")
(set #newname "LIBS:asl.library,orig")

; check for existence of "asl.library" and "asl.library,orig"
(if (exists #oldname (noreq)) (
  (if (not (exists #newname (noreq))) (
    (rename #oldname #newname (prompt (#rename-prompt #oldname #newname))
                              (help #rename-help) (confirm))
  ))
))

(complete 20)

(copylib (source (tackon #lib-source "asl.library"))
         (dest #lib-dest))

(complete 30)

(foreach #mcc-source "#?.mcc" (
 (copylib (source (tackon #mcc-source @each-name))
          (dest #mcc-dest)
          (prompt (#mcc-prompt @each-name #mcc-dest))
          (help #mcc-help) (confirm))
))

(complete 40)

(if (askbool (prompt #help-prompt) (help #help-help) (default 1)) (
 (copyfiles (source "Help/English/MUI-ASL.guide") (dest "HELP:english/"))
))

(complete 50)

;--------------------------------------------------------------------------
(if (> #cat-lang 0) (
  (if (not (exists #cat-dest)) (makedir #cat-dest))

  (if (bitand #cat-lang #def-lang-deutsch ) ((set #lang "deutsch" ) (P_copylang)))
  (if (bitand #cat-lang #def-lang-español ) ((set #lang "español" ) (P_copylang)))
  (if (bitand #cat-lang #def-lang-français) ((set #lang "français") (P_copylang)))
  (if (bitand #cat-lang #def-lang-italiano) ((set #lang "italiano") (P_copylang)))
  (if (bitand #cat-lang #def-lang-norsk   ) ((set #lang "norsk"   ) (P_copylang)))
  (if (bitand #cat-lang #def-lang-svenska ) ((set #lang "svenska" ) (P_copylang)))
;  (if (bitand #cat-lang #def-lang-polski  ) ((set #lang "polski"  ) (P_copylang)))
))

(complete 100)

;--------------------------------------------------------------------------
(exit)

;*** EOF ***